1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
|
/*
* Copyright (c) 2017 Arm Limited.
*
* SPDX-License-Identifier: MIT
*
* Permission is hereby granted, free of charge, to any person obtaining a copy
* of this software and associated documentation files (the "Software"), to
* deal in the Software without restriction, including without limitation the
* rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
* sell copies of the Software, and to permit persons to whom the Software is
* furnished to do so, subject to the following conditions:
*
* The above copyright notice and this permission notice shall be included in all
* copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
* OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
* SOFTWARE.
*/
#include "helpers.h"
#include "non_linear_filter_helpers.h"
/** This function applies a non linear filter on a 3x3 box basis on an input image.
*
* @note The needed filter operation is defined through the preprocessor by passing either -DMIN, -DMAX or -DMEDIAN.
*
* @param[in] src_ptr Pointer to the source image. Supported data types: U8
* @param[in] src_stride_x Stride of the source image in X dimension (in bytes)
* @param[in] src_step_x src_stride_x * number of elements along X processed per workitem(in bytes)
* @param[in] src_stride_y Stride of the source image in Y dimension (in bytes)
* @param[in] src_step_y src_stride_y * number of elements along Y processed per workitem(in bytes)
* @param[in] src_offset_first_element_in_bytes The offset of the first element in the source image
* @param[out] dst_ptr Pointer to the destination image. Supported data types: U8
* @param[in] dst_stride_x Stride of the destination image in X dimension (in bytes)
* @param[in] dst_step_x dst_stride_x * number of elements along X processed per workitem(in bytes)
* @param[in] dst_stride_y Stride of the destination image in Y dimension (in bytes)
* @param[in] dst_step_y dst_stride_y * number of elements along Y processed per workitem(in bytes)
* @param[in] dst_offset_first_element_in_bytes The offset of the first element in the destination image
*/
__kernel void non_linear_filter_box3x3(
IMAGE_DECLARATION(src),
IMAGE_DECLARATION(dst))
{
Image src = CONVERT_TO_IMAGE_STRUCT(src);
Image dst = CONVERT_TO_IMAGE_STRUCT(dst);
// Load values
uchar16 top = vload16(0, offset(&src, -1, -1));
uchar16 middle = vload16(0, offset(&src, -1, 0));
uchar16 bottom = vload16(0, offset(&src, -1, 1));
// Apply respective filter
#ifdef MIN
uchar16 tmp = min(top, min(middle, bottom));
uchar8 out = row_reduce_min_3(tmp);
#elif defined(MAX)
uchar16 tmp = max(top, max(middle, bottom));
uchar8 out = row_reduce_max_3(tmp);
#elif defined(MEDIAN)
uchar8 p0 = top.s01234567;
uchar8 p1 = top.s12345678;
uchar8 p2 = top.s23456789;
uchar8 p3 = middle.s01234567;
uchar8 p4 = middle.s12345678;
uchar8 p5 = middle.s23456789;
uchar8 p6 = bottom.s01234567;
uchar8 p7 = bottom.s12345678;
uchar8 p8 = bottom.s23456789;
uchar8 out = sort9(p0, p1, p2, p3, p4, p5, p6, p7, p8);
#else /* MIN or MAX or MEDIAN */
#error "Unsupported filter function"
#endif /* MIN or MAX or MEDIAN */
// Store result
vstore8(out, 0, dst.ptr);
}
/** This function applies a non linear filter on a 3x3 cross basis on an input image.
*
* @note The needed filter operation is defined through the preprocessor by passing either -DMIN, -DMAX or -DMEDIAN.
*
* @param[in] src_ptr Pointer to the source image. Supported data types: U8
* @param[in] src_stride_x Stride of the source image in X dimension (in bytes)
* @param[in] src_step_x src_stride_x * number of elements along X processed per workitem(in bytes)
* @param[in] src_stride_y Stride of the source image in Y dimension (in bytes)
* @param[in] src_step_y src_stride_y * number of elements along Y processed per workitem(in bytes)
* @param[in] src_offset_first_element_in_bytes The offset of the first element in the source image
* @param[out] dst_ptr Pointer to the destination image. Supported data types: U8
* @param[in] dst_stride_x Stride of the destination image in X dimension (in bytes)
* @param[in] dst_step_x dst_stride_x * number of elements along X processed per workitem(in bytes)
* @param[in] dst_stride_y Stride of the destination image in Y dimension (in bytes)
* @param[in] dst_step_y dst_stride_y * number of elements along Y processed per workitem(in bytes)
* @param[in] dst_offset_first_element_in_bytes The offset of the first element in the destination image
*/
__kernel void non_linear_filter_cross3x3(
IMAGE_DECLARATION(src),
IMAGE_DECLARATION(dst))
{
Image src = CONVERT_TO_IMAGE_STRUCT(src);
Image dst = CONVERT_TO_IMAGE_STRUCT(dst);
// Load values
uchar8 top = vload8(0, offset(&src, 0, -1));
uchar16 middle = vload16(0, offset(&src, -1, 0));
uchar8 bottom = vload8(0, offset(&src, 0, 1));
// Apply respective filter
#ifdef MIN
uchar8 tmp_middle = row_reduce_min_3(middle);
uchar8 out = min(tmp_middle, min(top, bottom));
#elif defined(MAX)
uchar8 tmp_middle = row_reduce_max_3(middle);
uchar8 out = max(tmp_middle, max(top, bottom));
#elif defined(MEDIAN)
uchar8 p0 = top.s01234567;
uchar8 p1 = middle.s01234567;
uchar8 p2 = middle.s12345678;
uchar8 p3 = middle.s23456789;
uchar8 p4 = bottom.s01234567;
uchar8 out = sort5(p0, p1, p2, p3, p4);
#else /* MIN or MAX or MEDIAN */
#error "Unsupported filter function"
#endif /* MIN or MAX or MEDIAN */
// Store result
vstore8(out, 0, dst.ptr);
}
/** This function applies a non linear filter on a 3x3 disk basis on an input image.
*
* @note The needed filter operation is defined through the preprocessor by passing either -DMIN, -DMAX or -DMEDIAN.
*
* @param[in] src_ptr Pointer to the source image. Supported data types: U8
* @param[in] src_stride_x Stride of the source image in X dimension (in bytes)
* @param[in] src_step_x src_stride_x * number of elements along X processed per workitem(in bytes)
* @param[in] src_stride_y Stride of the source image in Y dimension (in bytes)
* @param[in] src_step_y src_stride_y * number of elements along Y processed per workitem(in bytes)
* @param[in] src_offset_first_element_in_bytes The offset of the first element in the source image
* @param[out] dst_ptr Pointer to the destination image. Supported data types: U8
* @param[in] dst_stride_x Stride of the destination image in X dimension (in bytes)
* @param[in] dst_step_x dst_stride_x * number of elements along X processed per workitem(in bytes)
* @param[in] dst_stride_y Stride of the destination image in Y dimension (in bytes)
* @param[in] dst_step_y dst_stride_y * number of elements along Y processed per workitem(in bytes)
* @param[in] dst_offset_first_element_in_bytes The offset of the first element in the destination image
*/
__kernel void non_linear_filter_disk3x3(
IMAGE_DECLARATION(src),
IMAGE_DECLARATION(dst))
{
Image src = CONVERT_TO_IMAGE_STRUCT(src);
Image dst = CONVERT_TO_IMAGE_STRUCT(dst);
// Load values
uchar16 top = vload16(0, offset(&src, -1, -1));
uchar16 middle = vload16(0, offset(&src, -1, 0));
uchar16 bottom = vload16(0, offset(&src, -1, 1));
// Apply respective filter
#ifdef MIN
uchar16 tmp = min(top, min(middle, bottom));
uchar8 out = row_reduce_min_3(tmp);
#elif defined(MAX)
uchar16 tmp = max(top, max(middle, bottom));
uchar8 out = row_reduce_max_3(tmp);
#elif defined(MEDIAN)
uchar8 p0 = top.s01234567;
uchar8 p1 = top.s12345678;
uchar8 p2 = top.s23456789;
uchar8 p3 = middle.s01234567;
uchar8 p4 = middle.s12345678;
uchar8 p5 = middle.s23456789;
uchar8 p6 = bottom.s01234567;
uchar8 p7 = bottom.s12345678;
uchar8 p8 = bottom.s23456789;
uchar8 out = sort9(p0, p1, p2, p3, p4, p5, p6, p7, p8);
#else /* MIN or MAX or MEDIAN */
#error "Unsupported filter function"
#endif /* MIN or MAX or MEDIAN */
// Store result
vstore8(out, 0, dst.ptr);
}
|
